Урок 4.1. Иконки размером 4x4 пикселей: программа DRAWICON4(number)

Рисование иконок на графическом калькуляторе HP Prime

Иконки размером 4x4 пикселей: программа DRAWICON4(number)

Ввод: Действительные числа, целые числа

В конечном счете, число будет конвертировано в двоичное, каждый из 16 бит будет соответствовать матрице размером 4 х 4.

Если "включен" пункт "квадрат" (имеет значение 1), то будет нарисован квадрат.

Каждый пробел, если матрица представляет собой двоичный разряд: 2^0, 2^1, 2^2, 2^3, и т.д.

Бит наименьшего значения расположен снизу, это элемент в правом углу матрицы.

Вы можете сами выбирать, будут ли квадраты нарисованы черным или другим цветом.

Матрица битов размером 4х4 представлена в следующем виде:

[ [ 2^15, 2^14, 2^13, 2^12 ],

[ 2^11, 2^10, 2^9, 2^8 ],

[ 2^7, 2^6, 2^5, 2^4 ],

[ 2^3, 2^2, 2^1, 2^0 ] ]

Программа:

Текст после двойной косой черты // нужен только для пометок, его не обязательно вводить

EXPORT DRAWICON4(m)
BEGIN
  // EWS 12/28/2020

  // нужно ли пользователю вводить цвет?
  LOCAL ch, R, G, B;
  CHOOSE(ch, "Color?", "Black", "Yes");
  IF ch == 1 THEN
    ch := RGB(0, 0, 0);
    ELSE
    INPUT({R, G, B}, "Color Input",
    {"Red", "Green", "Blue"}, { }, {0, 0, 0});
    ch := RGB(R, G, B);
  END;

  // конвертировать m в действительное число, которое можно разделить
  // ввести 1 как целое число (#)
  IF TYPE(m) == 1 THEN
    m := B→R(m);
  END;

  // удалить части отрицательного значения и дроби (чтобы принимались такие числа как -12 и 34.55)
  m := ABS(IP(m));

  // разрешить m быть в текстовом формате, сохранив ее в M
  LOCAL M := m;

  // проверить верхний предел
  IF m > 65535 THEN
    MSGBOX("Excess of65535!");
    KILL;
  END;

  // разделить m на двоичные части и поместить их в нужно порядке
  LOCAL n := 15, r, c,
  mat := MAKELIST(0, X, 1, 16);

  REPEAT
    IF 2^n ≤ m THEN
      m := m-2^n;
      mat(n+1) := 1;
    END;
    n := n-1;
  UNTIL n < 0;
  mat := REVERSE(mat);

  // команду list2mat(список, количество столбцов) можно найти в каталоге
  mat := list2mat(mat, 4);

  // рисование границы и обозначения
  RECT();
  RECT_P(129, 79, 189, 139, RGB(0, 0, 255),
  RGB(255, 255, 255));
  TEXTOUT_P(M, 139, 0, 4, RGB(0, 128, 0));

  // использовать матрицу для рисования квадратов
  // пиксели x = столбцы, y = ряды
  FOR r FROM 1 TO 4 DO
    FOR c FROM 1 TO 4 DO

      IF mat(r, c) == 1 THEN
        RECT_P(129+15 * (c-1), 79+15 * (r-1),
        129+15*c, 79+15*r, ch);
      END;
    END;
  END;

  WAIT(0);

END;

В следующем разделе представлена версия рисования иконки размером 6x6: Программа DRAWICON6.